Механизм "Дополнительных отчетов и обработок в БСП"

Чтобы создать эту функцию, необходимо открыть режим конфигуратора и через основное меню «Файл» - «Новый…», создать внешний отчет. Открыть модуль объекта и добавить функцию «СведенияОВнешнейОбработке» с отметкой «Экспорт». В каждом дополнительном внешнем отчете в 1С 8.3 эта экспортная функция должна возвращать структуру с определенными ключами и значениями:

Функция СведенияОВнешнейОбработке() Экспорт
ПараметрыРегистрации = Новый Структура;
ПараметрыРегистрации.Вставить("Вид", "ДополнительнаяОбработка");
ПараметрыРегистрации.Вставить("Наименование", "Идентификация номенклатуры по коду ЕГАИС");
ПараметрыРегистрации.Вставить("Версия", "1.0");
ПараметрыРегистрации.Вставить("БезопасныйРежим", Истина);
ПараметрыРегистрации.Вставить("Информация", "Идентификация номенклатуры по коду ЕГАИС");
ТаблицаКоманд = ПолучитьТаблицуКоманд();

ДобавитьКоманду(ТаблицаКоманд,
"Идентификация номенклатуры",
"ИдентификацияНоменклатуры",
"ОткрытиеФормы",
//<Показывать оповещение>,
//<Модификатор>
);
ПараметрыРегистрации.Вставить("Команды", ТаблицаКоманд);
Возврат ПараметрыРегистрации;
КонецФункции


Функция ПолучитьТаблицуКоманд()
Команды = Новый ТаблицаЗначений;
Команды.Колонки.Добавить("Представление", Новый ОписаниеТипов("Строка"));
Команды.Колонки.Добавить("Идентификатор", Новый ОписаниеТипов("Строка"));
Команды.Колонки.Добавить("Использование", Новый ОписаниеТипов("Строка"));
Команды.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево"));
Команды.Колонки.Добавить("Модификатор", Новый ОписаниеТипов("Строка"));
Возврат Команды;
КонецФункции

Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование, ПоказыватьОповещение = Ложь, Модификатор = "")
НоваяКоманда = ТаблицаКоманд.Добавить();
НоваяКоманда.Представление = Представление;
НоваяКоманда.Идентификатор = Идентификатор;
НоваяКоманда.Использование = Использование;
НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;
НоваяКоманда.Модификатор = Модификатор;
КонецПроцедуры

• Вид

  Основным условием для регистрации разработки служит заполнение поля «Вид».

  Вид – определение типа доработки. Может принимать значения «ЗаполнениеОбъекта», «ДополнительнаяОбработка», «СозданиеСвязанныхОбъектов», «ДополнительныйОтчет» и многие другие.
  Минимальное (основное) описание параметров регистрации:

  Функция СведенияОВнешнейОбработке() Экспорт
  
  ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке();
  
  ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиЗаполнениеОбъекта();
  
  Возврат ПараметрыРегистрации;
  КонецФункции

  Значение поля «Вид»	Расположение команды	Расширение файла
  ПечатнаяФорма	В меню «Печать» на форме объекта или списка	epf
  ЗаполнениеОбъекта	В меню «Заполнить» на форме объекта или списка	epf
  СозданиеСвязанныхОбъектов	В меню «Создать на основании» — «Создание связанных объектов..» на форме объекта или списка	epf
  Отчет	В меню «Отчеты» на форме объекта или списка	erf
  ДополнительнаяОбработка	В списке соответствующих подсистем в меню «Сервис» — «Дополнительные обработки»	epf
  ДополнительныйОтчет	В списке соответствующих подсистем в меню «Сервис» — «Дополнительные отчеты»	erf

• Назначение

  Назначение – задается при добавлении функционала к конкретному документу или справочнику. Указывается один или перечень объектов конфигурации, к которым предназначен новый функционал. В случае обычного отчета прописывать не нужно.

• Команды

  Таблица, содержащая все необходимые команды с определенным набором характеристик. Отвечает за кнопку, запускающую обработку или отчет;

• БезопасныйРежим

  Принимает значения «Истина» или «Ложь», отвечает за безопасный режим запуска. Это специальный режим, когда для пользователя ограничиваются возможности. Если его включить, то в процессе работы отчета будут недоступны:

  1. Привилегированный режим;
  2. Библиотеки Dll;
  3. COM-соединение;
  4. Доступ к файлам и интернету.
• Версия

  Данные строкового типа для поддержания версионирования дополнительного отчета или обработки. Вспомогательный параметр;

• ВерсияБСП

  Иногда указывают для контроля совместимости механизма библиотеки стандартных подсистем. Зачастую не указывается;

• Информация

  Комментарий, дающий определение дополнительному отчету или обработке. Вспомогательный параметр.
  Конфигурация «Библиотека стандартных подсистем» имеет специальный помощник внедрения, позволяющий существенно сократить трудозатраты при разработке новой конфигурации. С помощью помощника можно пошагово указать нужные подсистемы и на выходе получить заготовку для будущей конфигурации.

  Что можно подключить:

  • Внешние обработки (файлы с расширением «epf»);
  • Внешние отчеты (файлы с расширением «erf»);
  • Виды разработок
  • Дополнительная обработка.
  • Дополнительный отчет.
  • Заполнение объекта. Возможность установить свои кнопки по заполнению документа.
  • Печатная кнопка.
  • Отчет. Прикрепляемый к справочникам и документам.
  • Создание связанных объектов.
  
  

  Возможности БСП:

  1. В документах можно добавлять кнопки по заполнению всего документа, кнопки по вводу на основании.
  2. Обработка может содержать несколько команд меню.
  3. Вводить на основании и заполнять объекты сразу на основании нескольких объектов.
  4. Задавать расписание выполнение серверных команд (на сервере).
  5. Задавать режим «Безопасный» или «Небезопасный», т.е. запускать обработку с учетом ограничением прав или полные права
  6. Задать режим использования: «Не использовать», «Отладка», «Использовать».
  7. Включить использование в формах объекта и в форма списков
  8. Привязать ко всем указанным объектам обработку или отчет.
  9. Настроить быстрый доступ к определенным командам внешних обработок.
  10. Возможность указать в каких разделах интерфейса должны появляться дополнительные обработки и отчеты.

Будьте уверены в надежности и стабильности своей системы с Тарифами 1С:ИТС.